[传奇脚本]GOM引擎传奇私服一条龙开测试区奖励记录功能脚本实例教程

技术员

[传奇脚本]GOM引擎传奇私服一条龙开测试区奖励记录功能脚本实例教程

添加使用请根据脚本内容路径，在自己传奇版本服务端内创建路劲为QuestDiary\测试区奖励\已记录测试奖励账号.txt等文本。

[@MAIN]
#IF
CHECKTEXTLIST ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt <$USERID>
#ACT
GetListString ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt 0 S$游戏点兑换数量
MOV N$游戏点记录数量 <$STR(S$游戏点兑换数量)>

#IF
NOT CHECKTEXTLIST ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt <$USERID>
#ACT
MOV N$游戏点记录数量 0

#if
#act
CLOSEMERCHANTBIGDLG
#say

　　　　　　　　　　　　　<测试区限时领取/FCOLOR=244>\　\
<>   <在测试区打到限时奖励可在开区后领取/FCOLOR=250>\ \
<>   <记录说明：测试区打到限时物品后将自动记录/FCOLOR=254>\
<>   <兑换说明：在新区正式开区之后就可以在这领取你兑换的测试区奖励了/FCOLOR=70>\　\
<>   <重要说明：请在正式开区后领取测试区奖励/FCOLOR=146>\
<>   <当前已记录积分:/FCOLOR=250>< <$STR(N$游戏点记录数量)>/FCOLOR=253> \ \
<>　　<记录测试区积分/@测试区游戏点111A>　　　      　　  　　　　　<领取测试区积分奖励/@领取测试区游戏点222A>

[@测试区游戏点111A]
#if
NOT CheckContainsText <$SERVERNAME> 测试
#ACT
messagebox 当前已经是正式开区，无法记录！！
break

#if
CHECKGAMEDIAMOND < 1
#act
MESSAGEBOX 你当前奖励积分为0，无法兑换！！！！
break

#IF
NOT CHECKTEXTLIST ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt <$USERID>
#ACT
AddTextListEx ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt <$USERID>
CreateFile ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt
AddTextListEx ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt <$GAMEDIAMOND>
GAMEDIAMOND = 0
MESSAGEBOX 　记录成功，\　\　请在新区开区之后在这领取积分！！！！
BREAK

#IF
CHECKTEXTLIST ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt <$USERID>
#ACT
GetListString ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt 0 S$游戏点兑换数量
MOV N$游戏点记录数量 <$STR(S$游戏点兑换数量)>
INC N$游戏点记录数量 <$GAMEDIAMOND>
GAMEDIAMOND = 0
CLEARNAMELIST ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt
AddTextListEx ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt <$STR(N$游戏点记录数量)>
MESSAGEBOX 　记录成功，\　\　请在新区开区之后在这领取积分！！！！
BREAK

[@领取测试区游戏点222A]
#if
CheckContainsText <$SERVERNAME> 测试
#ACT
messagebox 当前为测试区，请正式开区后再来领取！！
break

#IF
NOT CHECKTEXTLIST ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt <$USERID>
#ACT
messagebox 当前账号没有记录积分，或者已经领取过了！！！
break

#if
#ACT
GetListString ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt 0 S$游戏点兑换数量
MOV N$游戏点记录数量 <$STR(S$游戏点兑换数量)>
CLEARNAMELIST ..\QuestDiary\测试区奖励\测试账号记录\<$USERID>.txt
DELACCOUNTLIST ..\QuestDiary\测试区奖励\已记录测试奖励账号.txt
MOV P1 <$STR(N$游戏点记录数量)>
GAMEDIAMOND + <$STR(P1)>
MESSAGEBOX 领取成功！请检查积分的数量！
SENDMSG 0 玩家【<$USERNAME>】领取了测试区积分奖励，获得了积分【<$STR(P1)>】!!
break